project(libindicate_qt)
cmake_minimum_required(VERSION 2.6)
set(indicate_qt_VERSION 0.2.5.91)

# Bump this one when a binary-incompatible change is introduced
set(indicate_qt_lib_SOVERSION 1)

# Bump this one when the API is extended in a binary-compatible way
set(indicate_qt_lib_API_VERSION 4)

# Bump this one when changes do not extend the API
set(indicate_qt_lib_PATCH_VERSION 1)
set(indicate_qt_lib_VERSION ${indicate_qt_lib_SOVERSION}.${indicate_qt_lib_API_VERSION}.${indicate_qt_lib_PATCH_VERSION})

find_package(Qt4 REQUIRED)
find_package(PkgConfig REQUIRED)

add_definitions(-Wall)

pkg_check_modules(INDICATE REQUIRED indicate-0.7)

include_directories(
    ${QT_INCLUDE_DIR}
    ${QT_QTCORE_INCLUDE_DIR}
    ${QT_QTGUI_INCLUDE_DIR}
    ${INDICATE_INCLUDE_DIRS}
    )

link_directories(
    ${INDICATE_LIBRARY_DIRS}
    )

configure_file(indicate-qt.pc.in ${CMAKE_BINARY_DIR}/indicate-qt.pc @ONLY)

install(FILES ${CMAKE_BINARY_DIR}/indicate-qt.pc
    DESTINATION lib${LIB_SUFFIX}/pkgconfig)

add_subdirectory(src)
add_subdirectory(examples)
add_subdirectory(tests)

# Packaging
set(ARCHIVE_NAME libindicate-qt-${indicate_qt_VERSION})
add_custom_target(dist
    COMMAND bzr export --root=${ARCHIVE_NAME} ${CMAKE_BINARY_DIR}/${ARCHIVE_NAME}.tar.bz2
    WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})

add_custom_target(distcheck
    COMMAND cd ${CMAKE_BINARY_DIR}
    && rm -rf ${ARCHIVE_NAME}
    && tar xf ${ARCHIVE_NAME}.tar.bz2
    && mkdir ${ARCHIVE_NAME}/build
    && cd ${ARCHIVE_NAME}/build
    && cmake -DCMAKE_INSTALL_PREFIX=../install ..
    && make
    && make install
    && make check
    )
add_dependencies(distcheck dist)
